杰晶网络

使用vbscript脚本在表单中进行选择的代码
脚本专栏 2024/11/23 佚名
3 2
问：
嗨，Scripting Guy！我想创建一个带有四个单选按钮的表单，其中每个按钮各代表一台计算机。可以选择一个单选按钮，单击另一个按钮，然后脚本将在所选的计算机上运行。我怎样才能做到？

-- CW

答：
嗨，CW。如果我们所说的只是 VBScript 和 Windows Script Host，那么这个问题很简单：办不到。除了显示消息框以外，VBScript 和 WSH 都无法创建图形用户界面；没办法通过脚本使用单选按钮、列表框、下拉列表以及其他图形元素。

但是——噢，你们以前一定见过这种情况。没错：我们先告诉您某事办不到，然后再告诉您做事的方法。（嗨，每个人多需要点技巧，不是吗？）没错：虽然您不会只用 VBScript 实现这一点，但是完全可以使用 HTA（HTML 应用程序）来实现。

我们今天不会花太多时间来谈论 HTA；如果您对此感兴趣，可以查找大约一年前我们针对该主题推出的网络广播。可以说，HTA 使我们能够将 Internet Explorer 和脚本代码结合在一起，并反过来为脚本提供图形用户界面。虽然还有一些方法可以将图形用户界面合并到脚本中，但是对于才开始涉足 GUI 开发的用户来说，这可能是最简单的方法。

让我们先提供 HTA 的代码，然后再解释其工作原理。此示例 HTA 显示了四个单选按钮，其中每个按钮各代表一台计算机。选择一台计算机，并单击一个“Run Script（运行脚本）”按钮；完成后，将运行一个子例程。该程序将连接到已选定的计算机，然后报告该计算机上所安装的操作系统的名称。很不错吧？如要了解其工作原理，复制该代码，将其粘贴到记事本中，然后以 .hta 文件扩展名（比如：os_name.hta）保存文件。不要使用 .vbs 文件扩展名；那样行不通。扩展名必须是 .hta。

复制代码 代码如下:
<SCRIPT LANGUAGE="VBScript"> 

Sub RunScript 

    If ComputerOption(0).Checked Then 
        strComputer = ComputerOption(0).Value 
    End If 
    If ComputerOption(1).Checked Then 
        strComputer = ComputerOption(1).Value 
    End If 
    If ComputerOption(2).Checked Then 
        strComputer = ComputerOption(2).Value 
    End If 
    If ComputerOption(3).Checked Then 
        strComputer = ComputerOption(3).Value 
    End If 

    If strComputer = "" Then 
        Exit Sub 
    End If 

    Set objWMIService = GetObject _ 
        ("winmgmts:\\" & strComputer & "\root\cimv2") 
    Set colItems = objWMIService.ExecQuery _ 
        ("Select * From Win32_OperatingSystem") 
    For Each objItem in ColItems 
        Msgbox objItem.Caption 
    Next 

End Sub 

Sub CancelScript 
   Self.Close() 
End Sub 

</SCRIPT> 

<BODY> 
<input type="radio" name="ComputerOption" value="atl-ws-01">atl-ws-01<BR> 
<input type="radio" name="ComputerOption" value="atl-ws-02">atl-ws-02<BR> 
<input type="radio" name="ComputerOption" value="atl-ws-03">atl-ws-03<BR> 
<input type="radio" name="ComputerOption" value="atl-ws-04">atl-ws-04<P> 

<input id=runbutton class="button" type="button" value="Run Script" name="ok_button"  
onClick="RunScript"> 
&nbsp;&nbsp;&nbsp; 
<input id=runbutton class="button" type="button" value="Cancel" name="cancel_button"  
onClick="CancelScript"> 

</BODY> 

那么该代码包含哪些内容呢？我们可以将该代码分为四部分：其中有两个部分使用 HTML 标记来实现单选按钮以及“Run Script（运行脚本）”和“Cancel（取消）”按钮，而另外两个部分则根据您所点击的是“Run Script”还是“Cancel”来运行子例程。让我们更进一步了解这几个部分。

例如，HTML 代码在此显示这四个单选按钮。（如果您了解 HTML，那么这里就没有什么特别的；这是标准的 HTML 编码。）请注意，所有按钮都有相同的名称 (ComputerOption)；这是为了确保一次只能选择一个按钮。还要注意，每个按钮的“值”都被设为相应计算机的名称：

<BODY>
<input type="radio" name="ComputerOption" value="atl-ws-01">atl-ws-01<BR>
<input type="radio" name="ComputerOption" value="atl-ws-02">atl-ws-02<BR>
<input type="radio" name="ComputerOption" value="atl-ws-03">atl-ws-03<BR>
<input type="radio" name="ComputerOption" value="atl-ws-04">atl-ws-04<P>

这是显示“Run Script”和“Cancel”按钮的代码。这里的关键是“onClick”参数（在单击按钮时，指示该运行哪个子例程）。正如单击第一个按钮所能看到的，RunScript 子例程将运行；单击第二个按钮，CancelScript 子例程将运行：

<input id=runbutton class="button" type="button" value="Run Script" name="ok_button" 
onClick="RunScript">
&nbsp;&nbsp;&nbsp;
<input id=runbutton class="button" type="button" value="Cancel" name="cancel_button" 
onClick="CancelScript">

</BODY>

顺便说一下，CancelScript 子例程会关闭 HTA。正如您看到的，整个过程一点都不复杂：

Sub CancelScript
   Self.Close()
End Sub

现在——最终！——我们要遇到好事了。选择一个单选按钮，然后单击“Run Script”。我们的 HTA 是如何知道所选择的按钮以及如何知道对哪台计算机运行脚本？那么，到底要在哪里运行脚本呢？放松点；一切都在 RunScript 例程中：

复制代码 代码如下:
Sub RunScript 

    If ComputerOption(0).Checked Then 
        strComputer = ComputerOption(0).Value 
    End If 
    If ComputerOption(1).Checked Then 
        strComputer = ComputerOption(1).Value 
    End If 
    If ComputerOption(2).Checked Then 
        strComputer = ComputerOption(2).Value 
    End If 
    If ComputerOption(3).Checked Then 
        strComputer = ComputerOption(3).Value 
    End If 

    If strComputer = "" Then 
        Exit Sub 
    End If 

    Set objWMIService = GetObject _ 
        ("winmgmts:\\" & strComputer & "\root\cimv2") 
    Set colItems = objWMIService.ExecQuery _ 
        ("Select * From Win32_OperatingSystem") 
    For Each objItem in ColItems 
        Msgbox objItem.Caption 
    Next 

End Sub 

该子例程的前半部分用以确定所选的具体按钮。单选按钮（至少是具有相同名称的按钮）作为数组进行存储；数组中的第一个按钮是项目 0，第二个按钮是项目 1 等等。我们在这里所做的就是确定选择了哪个按钮；这可以通过查看每个按钮的“Checked（选定）”属性来实现。例如，这行代码用以确定按钮 0（数组中的第一个按钮）的“Checked”属性是否为 true；如果是的话，就表示所选定的就是该按钮：

If ComputerOption(0).Checked Then
如果“Checked”为 true，又如何呢？那么，随后将对变量 strComputer 指派该单选按钮的值（同时记住，该按钮的值恰好是计算机的名称）：

strComputer = ComputerOption(0).Value
如果“Checked”为 False，那又如何呢？没什么大不了；毕竟我们已经检查了每个单选按钮的值。迟早都会弄清楚选定了哪个按钮（而且只能有一个）。如果最终确定未选择任何按钮，那么就将退出该子例程。这就是该代码所完成的工作：

复制代码 代码如下:
If strComputer = "" Then 
    Exit Sub 
End If 

如果选择了一个按钮，那么 strComputer 将为我们所要连接的计算机的名称。这就是该子例程的后半部分所完成的工作：连接到指定计算机并返回其上所安装的操作系统的名称的是一个标准 WMI 脚本。

哟！我们敢打赌，对于能完成这件事，您会感到很高兴，不是吗？或者，至少如果我们的确做到了这一点，您就会高兴。但是，还有一点需要指出。我们在此提供的示例 HTA 可以检索计算机上所安装的操作系统的名称，然后将其显示在消息框中。这很好，但是比方说您想显示计算机上所安装的所有服务的列表，又该怎么办呢？这时，您会发现自己将应答几十个消息框。这可不是您我所希望得到的用户体验。

那么，能否解决这个问题？当然可以。我们不想在这方面多花时间，但是需要做几件事。首先，我们在 HTA 中添加了一个 SPAN 区域；这只是屏幕上的一个可识别的区域，可以在其中写入信息。使用此类代码将 SPAN（附带 DataArea 的 ID）放置在按钮的下方：

<P> <span id=DataArea></span>
其次，需要收集该数据，并将其全都保存到一个变量中，而不在一个消息框中显示所有数据。该代码将变量 strText 的值设为当前在 strText 中的任何值加上“caption”属性的值，再加上 <BR> 标记（在 HTML 脚本中相当于按键盘上的“ENTER”键）：

strText = strText & objItem.Caption & "<BR>"
最后，需要将 SPAN 的“InnerHTML”属性设为变量 strText 的值：

DataArea.InnerHTML = strText
都明白了吗？另外，为了避免过多的解释，这里有个修改过的 HTA，可以收集计算机上所安装的所有服务的名称，然后自动将这些名称写入 HTA 中：

复制代码 代码如下:
<SCRIPT LANGUAGE="VBScript"> 

Sub RunScript 

    If ComputerOption(0).Checked Then 
        strComputer = ComputerOption(0).Value 
    End If 
    If ComputerOption(1).Checked Then 
        strComputer = ComputerOption(1).Value 
    End If 
    If ComputerOption(2).Checked Then 
        strComputer = ComputerOption(2).Value 
    End If 
    If ComputerOption(3).Checked Then 
        strComputer = ComputerOption(3).Value 
    End If 

    If strComputer = "" Then 
        Exit Sub 
    End If 

    Set objWMIService = GetObject _ 
        ("winmgmts:\\" & strComputer & "\root\cimv2") 
    Set colItems = objWMIService.ExecQuery _ 
        ("Select * From Win32_Service") 
    For Each objItem in ColItems 
        strText = strText & objItem.Name & "<BR>" 
    Next 

    DataArea.InnerHTML = strText 

End Sub 

Sub CancelScript 
   Self.Close() 
End Sub 

</SCRIPT> 

<BODY> 
<input type="radio" name="ComputerOption" value="atl-ws-01">atl-ws-01<BR> 
<input type="radio" name="ComputerOption" value="atl-ws-02">atl-ws-02<BR> 
<input type="radio" name="ComputerOption" value="atl-ws-03">atl-ws-03<BR> 
<input type="radio" name="ComputerOption" value="atl-ws-04">atl-ws-04<P> 

<input id=runbutton class="button" type="button" value="Run Script" name="ok_button"  
onClick="RunScript"> 
&nbsp;&nbsp;&nbsp; 
<input id=runbutton class="button" type="button" value="Cancel" name="cancel_button"  
onClick="CancelScript"> 
<P> 
<span id=DataArea></span> 
</BODY> 

标签：
使用vbscript脚本在表单中进行选择的代码
免责声明：本站文章均来自网站采集或用户投稿，网站不提供任何软件下载或自行开发的软件！ 如有用户或公司发现本站内容信息存在侵权行为，请邮件告知！ 858582#qq.com
www.imxmx.com 杰晶网络
8,675无损音乐
1,324高清电影
213破解软件
120,141站长资源
一句话新闻
苹果官宣WWDC 2024！预计会有大批AI功能 - 2024/11/23

3月27日消息，苹果宣布2024年全球开发者大会（WWDC）将于6月10日至6月14日举行，巧合的是，这次大会与端午假期重合。

苹果官方表示：

在线参加 Apple 每年规模最大的开发者盛会。亲眼见证 Apple 最新平台、技术和工具的发布。了解如何创建和改进你的 App 和游戏。与 Apple 设计师和工程师互动交流，与全球开发者社区建立联系。以上活动均免费在线举行。

探索各种新的工具、框架和功能，助力你打造出理想的 App 和游戏。通过视频讲座学习新技能，与 Apple 专家进行一对一会面，以推进你的项目，完善你的构思。

Swift Student Challenge 旨在支持和鼓舞下一代开发者、创作者和企业家。太平洋时间 3 月 28 日，我们将公布今年的获奖者名单。获奖者将有资格参加在 Apple Park 举办的特别活动。我们还会选出 50 名杰出获胜者，他们将受邀前往库比提诺，获得为期三天的非凡体验，包括参加 Apple Park 的特别活动。

RTX 5090要首发 性能要翻倍！三星展示GDDR7显存

三星在GTC上展示了专为下一代游戏GPU设计的GDDR7内存。

首次推出的GDDR7内存模块密度为16GB，每个模块容量为2GB。其速度预设为32 Gbps（PAM3），但也可以降至28 Gbps，以提高产量和初始阶段的整体性能和成本效益。

据三星表示，GDDR7内存的能效将提高20%，同时工作电压仅为1.1V，低于标准的1.2V。通过采用更新的封装材料和优化的电路设计，使得在高速运行时的发热量降低，GDDR7的热阻比GDDR6降低了70%。

更新动态

友情链接

杰晶网络 DDR爱好者之家 南强小屋 黑松山资源网 白云城资源网